http://dieseyer.de • all rights reserved • © 2011 v11.4

'*** v5.6 *** www.dieseyer.de *******************************
'
' Datei: permanentpopup.vbs
' Autor: dieseyer@gmx.de
' Auf: www.dieseyer.de
'
' Eine PopUp-Meldung, die sich nicht weg klicken läßt.
'
'************************************************************
Option Explicit

Dim fso, SkriptName, Text

Set fso = WScript.CreateObject("Scripting.FileSystemObject")


' wo soll das (Tochter-) Skript ("-aktive.vbs") stehen?
SkriptName = fso.GetBaseName( WScript.ScriptName ) & "-aktive.vbs" ' im Skript-Verzeichnis
SkriptName = fso.GetSpecialFolder( 2 ) & "\-aktive.vbs" ' im User-Abhängigen Temp-Verzeichnis
' MsgBox SkriptName, , "18 :: " & WScript.ScriptName



' was soll das (Tochter-) Skript anzeigen?
Text = "Dies ist eine sehr wichtige Nachricht!"



' das (Tochter-) Skript erzeugen und aufrufen
PermanentPopUp SkriptName, Text ' Function Aufruf



' das Skript hat jetzt viel und wichtiges zu tun - 60s lang
WScript.Sleep 60*1000



' das Skript ist fertig mit: viel und wichtiges zu tun
fso.DeleteFile( SkriptName )



WScript.Sleep 1*1000

MsgBox WScript.ScriptName & " . . . ist zu Ende", , WScript.ScriptName

WScript.Quit


'*** v5.6 *** www.dieseyer.de *******************************
Sub PermanentPopUp( SkriptName, Text )
'*************************************************************

Dim AKTIVvbs
Dim fso, WSHShell

Set WSHShell = WScript.CreateObject("WScript.Shell")
Set fso = WScript.CreateObject("Scripting.FileSystemObject")

Set AKTIVvbs = Fso.OpenTextFile( SkriptName , 2, true)
AKTIVvbs.WriteLine "Set WSHShell = WScript.CreateObject(""WScript.Shell"") "
AKTIVvbs.WriteLine "Set fso = WScript.CreateObject(""Scripting.FileSystemObject"") "
AKTIVvbs.WriteLine "Txt = """ & Text & """"
AKTIVvbs.WriteLine "Titel = ""!!! ACHTUNG !!!"" "
AKTIVvbs.WriteLine "Do"
' AKTIVvbs.WriteLine "WshShell.Popup Txt, 2, Titel "
AKTIVvbs.WriteLine "WshShell.Popup Txt, 2, Titel, vbSystemModal "
AKTIVvbs.WriteLine "if not fso.FileExists( WScript.ScriptFullName ) Then Exit Do"
AKTIVvbs.WriteLine "Loop"
AKTIVvbs.WriteLine "WshShell.Popup "". . . das wars"", 3, Titel "
AKTIVvbs.Close
Set AKTIVvbs = Nothing

WSHShell.Run SkriptName

End Sub ' PermanentPopUp( SkriptName, Text )

http://dieseyer.de • all rights reserved • © 2011 v11.4