'*** v2.1 *** www.dieseyer.de ******************************* 

' 

' Datei:  adminstart.vbs 

' Autor:  (C) 2002 by EagleSoft Ltd. / Roland Weisskopf 

' Auf:    www.dieseyer.de 

' 

'  Führt Scripte und Programme unter einem anderen Useraccount aus. 

'  Alle notwendigen Angaben wie Benutzername und Passwort 

'  können über die Kommandozeile mitgegeben werden. 

' 

'  Es können Scripte für WSCRIPT und CSCRIPT gestartet werden. 

' 

'  Known Limits 

'  ============ 

' 

'  - Das Script ist für Deutsch ausgelegt. Bei anderen Sprachen muss die 

'    Variable strConsole entsprechend angepasst werden. 

' 

'  - Scripte für die Konsole können nur gestartet werden, wenn das Passwort 

'    als Parameter mitgegeben wird. 

' 

'  - Die Wartezeiten zum Aktivieren der Applikationsfenster kann bei 

'    Bedarf über die beiden Variablen intSleepShort (Wartezeit nach 

'    AppActivate bis zum Senden von Tastenanschlägen) und intSleepLong 

'    (Wartezeit nach Programmstart runas/cmd) verändert werden. 

' 

'  - Werden Useraccount und Passwort fix einprogrammiert, muss das 

'    Script mit dem Encoder codiert werden. 

' 

' 

'  Starparameter (Reihenfolge spielt keine Rolle) 

'  ============= 

' 

'  /U Angabe des Useraccounts. Der Name muss komplett notiert werden und 

'     ohne Leerschlag an /U angefügt werden. Parameter ist zwingend. 

'     /Udomain\administrator oder /Ucomputername\administrator 

' 

'  /S Angabe der Scripts, das gestartet werden soll. Wenn das Script im 

'     gleichen Verzeichnis liegt wie AdminStart.vbs, muss der Pfad zum 

'     Script nicht angegeben werden. Im andern Fall ist das Script mit 

'     der kompletten Pfadangabe zu übergeben. Parameter ist zwingend. 

'     /Smeinscript.vbs  oder /S\\server\ablage$\meinscript.vbs 

' 

'     Wichtig: Wenn für das Script selbst Parameter übergeben werden 

'     müssen, muss der ganze Schalter /S in Anführungszeichen gefasst 

'     werden: "/Smeinscript.vbs /parameter2 /parameter2" 

' 

'  /P Übergibt das Passwort zum Useraccount. Ohne Angabe des Passwortes 

'     wird es von RunAs.Exe über die Konsole abgefragt. 

' 

'  /C Lässt das Script mit CScript ablaufen oder startet ein Windows- 

'     Programm. Ohne diesen Schalter wird immer ein Script mit WScript 

'     gestartet. 

'     /C = starte Script mit CSCRIPT 

'     /CP = starte eine Windows-Programm. In diesem Fall muss mit /S 

'           der komplette Pfad angebenen werden -> /sc:\winnt\notepad.exe 

' 

'  (C) 2002 by EagleSoft Ltd. / Roland Weisskopf 

' 

'************************************************************ 

 

Option Explicit ' Siehe http://dieseyer.de/dse-wsh-lernen.html#OptionExpl 

 

Dim strInterpreter(1) 

Dim strRunAsPrefix, strScript, strUser, strPass, strRunCommand 

Dim objShell 

Dim intLoop, intMode, intSleepShort, intSleepLong 

Dim blnPass 

Const cCScript = 0 

Const cWScript = 1 

Const cProgram = 2 

Dim strConsole 

 

'* Presets zum Anpassen 

'############################################### 

'# Werte User und PW nach Bedarf fix eintragen 

'# und mit SCRENC dieses File codieren 

'############################################### 

' Useraccount: domain\account o. machine\account 

strUser = "" 

' Passwort 

strPass = "" 

'############################################### 

' Pfad, Name und Parameter für das Script 

strScript = "" 

' Sprachenanpassung von 'ausgeführt als' 

strConsole = "cmd.exe /k ( ausgeführt als " 

' Wartezeit nach Fensterfokusierung 

intSleepShort = 250 

' Wartezeit nach Run-Command 

intSleepLong = 500 

' Standardmodus 

intMode = cWScript 

 

'* Presets (nicht ändern!!) 

strRunAsPrefix = GetSystem32 & "\runas /user:" 

strInterpreter(0) = "cmd.exe /k" 

strInterpreter(1) = "wscript " 

blnPass = vbFalse 

Set objShell = WScript.CreateObject("WScript.Shell") 

 

'* Command Line Parameter auswerten 

if Wscript.Arguments.Count > 0 then 

  for intLoop = 0 to Wscript.Arguments.Count-1 

    if left(ucase(WScript.Arguments.Item(intLoop)),2) = "/C" then  

      intMode = cCScript 

      if right(ucase(WScript.Arguments.Item(intLoop)),1) = "P" then intMode=cProgram 

    end if 

    if left(ucase(WScript.Arguments.Item(intLoop)),2) = "/U" then  

      if len(WScript.Arguments.Item(intLoop))>2 then 

        strUser = right(WScript.Arguments.Item(intLoop),len(WScript.Arguments.Item(intLoop))-2) & " " 

      end if 

    end if 

    if left(ucase(WScript.Arguments.Item(intLoop)),2) = "/P" then  

      if len(WScript.Arguments.Item(intLoop))>2 then 

        strPass = right(WScript.Arguments.Item(intLoop),len(WScript.Arguments.Item(intLoop))-2) 

        blnPass = vbTrue 

      end if 

    end if 

    if left(ucase(WScript.Arguments.Item(intLoop)),2) = "/S" then  

      if len(WScript.Arguments.Item(intLoop))>2 then 

        strScript = right(WScript.Arguments.Item(intLoop),len(WScript.Arguments.Item(intLoop))-2) 

        Dim intPosP  

        intPosP=inStr(1,strScript,":\",vbTextCompare) 

        if intPosP=0 or intPosP>4 then 

          intPosP=inStr(1,strScript,"\\",vbTextCompare) 

          if intPosP=0 or intPosP>3 then strScript = strScriptPath & "\" & strScript 

        end if 

      end if 

    end if 

  next 

end if 

 

if strScript = "" then MissingParameter 

if strUser = "" then MissingParameter 

if right(strUser,1)<>" " then strUser = strUser &  " "  

if strPass<>"" then blnPass = vbTrue 

if (intMode=cCScript) and (not blnPass) then MissingParameter 

 

select case intmode 

case cCScript 

  strRunCommand = strRunAsPrefix & strUser & chr(34) & strInterpreter(intMode) & chr(34) 

case cWScript 

  strRunCommand = strRunAsPrefix & strUser & chr(34) & strInterpreter(intMode) & strScript & chr(34) 

case cProgram 

  strRunCommand = strRunAsPrefix & strUser & chr(34) & strScript & chr(34) 

end select 

' MsgBox strRunCommand, , "148 :: " 

objShell.Run strRunCommand 

WScript.Sleep intSleepLong 

if blnPass then 

  objShell.AppActivate GetSystem32 & "\runas.exe" 

  WScript.Sleep intSleepShort 

' MsgBox strPass & "{enter}" & vbCRLF & intMode & vbCRLF & GetSystem32 & "\runas.exe", , "156 :: " 

  objShell.Sendkeys strPass & "{enter}" 

  select case intMode 

  case cCScript 

    WScript.Sleep intSleepLong 

    objShell.AppActivate strConsole & strUser & ")" 

    WScript.Sleep intSleepShort 

    objShell.Sendkeys "cscript " & chr(34) & strScript & chr(34) & "{enter}"   

  end select 

end if 

 

Set objShell = nothing 

WScript.Quit 

 

'******************************************************************** 

'* Sub MissingParameter  

'* Benötigte Parameter wurden nicht übergeben 

'******************************************************************** 

Private Sub MissingParameter 

  WScript.Echo "Es fehlt mindestens einer der benötigten Startparameter. Prüfe die Eingabe für /U, /P und /C." 

  WScript.Quit 

End Sub 

 

'******************************************************************** 

'* Function strScriptPath  

'* Ermittle den Serverpfad des aktuellen Scripts  

'******************************************************************** 

Private Function strScriptPath 

  strScriptPath = left(Wscript.ScriptFullName,len(Wscript.ScriptFullName)-len(Wscript.ScriptName)-1) 

End Function 

 

'******************************************************************** 

'* Function GetSystem32 

'* Gibt das lokale System32-Verzeichnis zurück 

'******************************************************************** 

Private Function GetSystem32 

  Dim strTemp 

  strTemp = strEnviron("windir") 

  GetSystem32 = strTemp & "\system32" 

End Function 

 

'******************************************************************** 

'* Function strEnviron 

'* Gibt Umgebungsvariablen von Windows zurück 

'******************************************************************** 

Private Function strEnviron(strVarName) 

  Dim objWindows 

  Set objWindows = WScript.CreateObject("WScript.Shell") 

  strEnviron = objWindows.ExpandEnvironmentStrings("%" + strVarName + "%") 

  Set objWindows = Nothing 

End Function