'*** v4.7 *** www.dieseyer.de ****************************** 

' File:   datei-in-datum-sichern.vbs 

' Autor:  dieseyer@gmx.de  

'         dieseyer.de 

'  

' Skript überprüft, ob es eine bestimmte Datei gibt, kopiert  

' diese in ein Sicherungsverzeichnis und benennt sie dabei  

' um - der neue Dateiname ist der Kopierzeitpunkt. 

' Die alte Datei wird gelöscht. 

'*********************************************************** 

 

Option Explicit 

 

Dim fso 

Dim Dateiname, ZielVerz, Intervall, i, text 

 

Set fso      = WScript.CreateObject("Scripting.FileSystemObject") 

 

 

Dateiname = "c:\temp\wichtig.txt"    ' Dateiname mit komplettem Pfad 

 

ZielVerz  = "d:\wichtige"            '  

ZielVerz  = ZielVerz & "\" 

 

Intervall = 10                       ' Testintervall in Sekunden 

 

    i = 0 

Do 

  if fso.FileExists( Dateiname ) Then  

    i = i +1 

    fso.CopyFile   Dateiname, ZielVerz & DatumZeit & ".txt"  

    Fso.DeleteFile Dateiname 

    Text = MsgBox( Dateiname & vbCRLF & vbCRLF & "zum " & i &". mal gefunden - Skript beenden?", 4+256, WScript.ScriptName) 

    If Text = vbYes then Exit Do 

  End If 

 

  if fso.FileExists( fso.GetBaseName( WScript.ScriptName) & ".end" ) Then Exit Do 

 

  WScript.Sleep Intervall * 1000 

 

Loop 

 

MsgBox Dateiname & vbCRLF & vbCRLF & "zum " & i &". mal gefunden - Skript - Ende.", , WScript.ScriptName 

 

  if fso.FileExists( fso.GetBaseName( WScript.ScriptName) & ".end" ) Then fso.DeleteFile( fso.GetBaseName( WScript.ScriptName) & ".end" )  

 

WScript.Quit 

 

'*** v4.7 *** www.dieseyer.de ****************************** 

Function DatumZeit 

'***********************************************************  

' gibt ein Zeichenfolge zurück, die Datum / Zeit enthält 

' und als Dateiname / Verzeichnisnae verwendet werden kann 

 

Dim Zeit 

  

Zeit = now()  

  

' zweistellige Jahreszahl  

DatumZeit = Right(Year(Zeit),2)   

  

' zweistellige Monatszahl  

If     Len(Month(Zeit))  = 1 then DatumZeit = DatumZeit & "-0" & Month(Zeit)  

If not Len(Month(Zeit))  = 1 then DatumZeit = DatumZeit & "-"  & Month(Zeit)  

  

' zweistellige Tageszahl  

If     Len(Day(Zeit))    = 1 then DatumZeit = DatumZeit & "-0" & Day(Zeit)  

If not Len(Day(Zeit))    = 1 then DatumZeit = DatumZeit & "-"  & Day(Zeit)  

  

' zweistellige Stundezahl  

If     Len(Hour(Zeit))   = 1 then DatumZeit = DatumZeit & "_0" & Hour(Zeit)  

If not Len(Hour(Zeit))   = 1 then DatumZeit = DatumZeit & "_"  & Hour(Zeit)  

  

' zweistellige Minutenzahl  

If     Len(Minute(Zeit)) = 1 then DatumZeit = DatumZeit & "'0" & Minute(Zeit)  

If not Len(Minute(Zeit)) = 1 then DatumZeit = DatumZeit & "'"  & Minute(Zeit)  

  

' zweistellige Sekundenzahl  

If     Len(Second(Zeit)) = 1 then DatumZeit = DatumZeit & "'0" & Second(Zeit)  

If not Len(Second(Zeit)) = 1 then DatumZeit = DatumZeit & "'"  & Second(Zeit)  

  

End Function ' DatumZeit