'*** v9.7 *** www.dieseyer.de ******************************* 

' 

' Datei:  PC–Konfiguration für WinTuC_FwMgr.vbs 

' Datei:  PCKonfiguration-WinTuC_FwMgr.vbs 

' Autor:  xxx.dexter.xxx@googlemail.com 

' Auf:    www.dieseyer.de / www.wintuc.de 

' 

' Ursprünglich war vorgesehen, die PC-Konfiguration vor dem 

' 'Freischalten' für WinTuC zu speichern, um diese ggf. 

' zurück stellen zu können. 

' Da für das 'Freischalten' an dem PC sehr wahrscheinlich 

' eine lokale Anmeldung mit einem Admin-User erforderlich 

' ist, kann man gleich WinTuC vom USB-Stick starten - damit 

' ist der einmalige WinTuC-Einsatz erledigt. Und soll WinTuC 

' mehrmals eingesetzt werden, ist das zurück setzen auf eine 

' ältere Konfiguration nicht erforderlich. 

' 

' Windows Firewall Reference 

' http://msdn.microsoft.com/en-us/libr...52(VS.85).aspx 

' 

'************************************************************ 

 

Option Explicit ' Siehe http://dieseyer.de/dse-wsh-lernen.html#OptionExpl 

 

Const NET_FW_SCOPE_LOCAL_SUBNET = 1           ' Nur eigenes Netzwerk (Subnetz) 

Const NET_FW_SERVICE_FILE_AND_PRINT = 0       ' Datei- und Druckerfreigabe 

Dim FirewallManager 

  

ON ERROR RESUME NEXT 

Set FirewallManager = CreateObject("HNetCfg.FwMgr") 

If Err <> 0 Then 

  WScript.Echo "Windows Firewall kann nicht bestimmt werden!" 

  WScript.Quit(1) 

End If 

ON ERROR GOTO 0 

  

'*** Remoteverwaltung aktivieren 

'* ----------------------------- 

'* -> DCE Endpoint Resolution (TCP 135) 

'* -> SMB über TCP (TCP 445) 

  

With FirewallManager.LocalPolicy.CurrentProfile.RemoteAdminSettings 

  If Not .Enabled Then 

    .Enabled = TRUE 

    .Scope = NET_FW_SCOPE_LOCAL_SUBNET 

  End If 

End With 

  

'*** Datei- und Druckerfreigabe aktivieren 

'* --------------------------------------- 

'* -> NetBIOS-Sitzungsdienst (TCP 139) 

'* -> SMB über TCP (TCP 445) 

'* -> NetBIOS-Namensdienst (UDP 137) 

'* -> NetBIOS-Datagrammdienst (UDP 138) 

  

With FirewallManager.LocalPolicy.CurrentProfile.Services.Item(NET_FW_SERVICE_FILE_AND_PRINT) 

  If Not .Enabled Then 

    .Enabled = TRUE 

    .Scope = NET_FW_SCOPE_LOCAL_SUBNET  

  End If 

End with