http://dieseyer.de • all rights reserved • © 2011 v11.4

'v6.1*****************************************************
' File: wmi-netzwerkeigenschaften.vbs
' Autor: dieseyer@gmx.de
' dieseyer.de
'
'
' Listet die Netzwerkeigenschaften von (remote) PCs.
' Protokoll am Besten mit baretail beobachten.
' (http://www.baremetalsoft.com/baretail/)
'*********************************************************

Option Explicit ' Siehe http://dieseyer.de/dse-wsh-lernen.html#OptionExpl

Dim WSHNet : Set WSHNet = WScript.CreateObject("WScript.Network")
Dim myFS : Set myFS = CreateObject("Scripting.FileSystemObject")
Dim myOutput : Set myOutput = myFS.OpenTextFile( "netzwerk.txt", 8, true ) ' 8 : erweitern, notfals anlegen'

Dim i, Tst

myOutput.WriteLine vbCRLF & String( 50, "-" ) & vbCRLF & WScript.ScriptName & " - Skripstart." & vbCRLF & String( 50, "-" )

For i = 20 to 22
Tst = "192.168.1." & i ' ergibt 192.168.1.20 . . . 192.168.1.22
myOutput.Write Tst & vbTab & " wird getestet . . . "
myOutput.Write Netzwerkinformationen( Tst )
Next

myOutput.WriteLine WScript.ScriptName & " - Skriptende." & vbCRLF

MsgBox "Skript - Ende", , WScript.ScriptName

WScript.Quit


'*********************************************************
Function Netzwerkinformationen( strComputer )
'*********************************************************
Dim objWMIService, objAdapter, colAdapters
Dim Ausgabe, i
on error resume next
'####################################################
'####### Script zum Ausgeben der #######
'####### Netzwerkeigenschaften #######
'####### 24.04.2003 Thumbs #######
'####################################################
Set objWMIService = GetObject ("winmgmts:" & "!\\" & strComputer & "\root\cimv2")
Netzwerkinformationen = strComputer & vbTab & " ist nicht erreichbar! " & now() & vbCRLF & vbCRLF

if err.Number <> 0 Then Exit Function ' PC ist nicht erreichbar

Set colAdapters = objWMIService.ExecQuery ("Select * from Win32_NetworkAdapterConfiguration Where IPEnabled = True")

Ausgabe = vbCRLF & now() & vbCRLF
For Each objAdapter in colAdapters
Ausgabe = Ausgabe & "=>> Host name: " & objAdapter.DNSHostName & vbCRLF
Ausgabe = Ausgabe & "DNS domain: " & objAdapter.DNSDomain & vbCRLF
Ausgabe = Ausgabe & "DNS suffix search list: " & objAdapter.DNSDomainSuffixSearchOrder & vbCr
Ausgabe = Ausgabe & "Description: " & objAdapter.Description & vbCRLF
Ausgabe = Ausgabe & "Physical address: " & objAdapter.MACAddress & vbCRLF
Ausgabe = Ausgabe & "DHCP enabled: " & objAdapter.DHCPEnabled & vbCRLF
If Not IsNull(objAdapter.IPAddress) Then
For i = LBound(objAdapter.IPAddress) To UBound(objAdapter.IPAddress)
Ausgabe = Ausgabe & "IP address: " & objAdapter.IPAddress(i) & vbCRLF
Next
End If
If Not IsNull(objAdapter.IPSubnet) Then
For i = LBound(objAdapter.IPSubnet) To UBound(objAdapter.IPSubnet)
Ausgabe = Ausgabe & "Subnet: " & objAdapter.IPSubnet(i) & vbCRLF
Next
End If
If Not IsNull(objAdapter.DefaultIPGateway) Then
For i = LBound(objAdapter.DefaultIPGateway) To UBound(objAdapter.DefaultIPGateway)
Ausgabe = Ausgabe & "Default gateway: " & objAdapter.DefaultIPGateway(i) & vbCRLF
Next
End If
Ausgabe = Ausgabe & "DHCP server: " & objAdapter.DHCPServer & vbCRLF
If Not IsNull(objAdapter.DNSServerSearchOrder) Then
For i = LBound(objAdapter.DNSServerSearchOrder) To UBound(objAdapter.DNSServerSearchOrder)
Ausgabe = Ausgabe & "DNS server: " & objAdapter.DNSServerSearchOrder(i) & vbCRLF
Next
End If
Ausgabe = Ausgabe & "Primary WINS server: " & objAdapter.WINSPrimaryServer & vbCRLF
Ausgabe = Ausgabe & "Secondary WINS server: " & objAdapter.WINSSecondaryServer & vbCRLF
Ausgabe = Ausgabe & "Lease obtained: " & objAdapter.DHCPLeaseObtained & vbCRLF
Ausgabe = Ausgabe & "Lease expires: " & objAdapter.DHCPLeaseExpires & vbCRLF
Next

Netzwerkinformationen = Ausgabe & vbCRLF

End Function ' Netzwerkinformationen( strComputer )

http://dieseyer.de • all rights reserved • © 2011 v11.4